Impossible d'utiliser la fonction «modifier le commentaire dans clic droit personnalisé

2

Bonjour à tous, 

Dans mon menue personnalisé

- Aucun problème pour faire un nouveau commentaire dans une cellule

- Aucun probème pour masquer ce commentaire

- Impossible d'utiliser la fonction «modifier le commentaire» toujours avec le click droit.

Note:  je désire conserver les fonctions des commentaires sans passer par le ruban de Excel.


Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
Dim CB As CommandBar
Dim CT As CommandBarControl
'--- Met tous les contrôles invisibles ---
Set CB = Application.CommandBars("Cell")
For Each CT In CB.Controls
  CT.Visible = False
Next CT
'--- Les boutons personnalisés ---
With Application.CommandBars("Cell")
  '/// Mettre les boutons qui vont bien ///
  Set CT = .Controls.Add(Type:=msoControlButton, ID:=19, temporary:=True)  'COPIER
  Set CT = .Controls.Add(Type:=msoControlButton, ID:=22, temporary:=True)  'COLLER
  Set CT = .Controls.Add(Type:=msoControlButton, ID:=1592, temporary:=True) 'SUPPRIMER LE COMMENTAIRE
  Set CT = .Controls.Add(Type:=msoControlButton, ID:=1593, temporary:=True) 'MASQUER LE COMMENTAIRE
  Set CT = .Controls.Add(Type:=msoControlButton, ID:=3125, temporary:=True) 'EFFACER LE CONTENU (CELLULE)
  Set CT = .Controls.Add(Type:=msoControlButton, ID:=1589, temporary:=True) 'INSERER UN COMMENTAIRE
 
  '////////////////////////////////////////
  .ShowPopup
End With
'---
Cancel = True


End Sub


Merci à l'avance,


    BPPPI Posté le 11 février, 22:39
    par BPPPI
    Répondre
    2

    Bonjour,


    Essaies :

    Private Sub Worksheet_BeforeRightClick(ByVal Target As Range, Cancel As Boolean)
    Dim CB As CommandBar
    Dim CT As CommandBarControl
    Const N$ = "19,22,755,2031,1595,3125,1589,1592,1593,2056,"
      Set CB = Application.CommandBars("Cell")
      For Each CT In CB.Controls
      If InStr(1, N, CT.ID & ",") > 0 Then
      CT.Visible = True
      Else
      CT.Visible = False
      End If
      Next CT
    End Sub

    Patrice33740 Posté le 12 février, 00:14
    par Patrice33740
    0

    Très fort!

    Merci beaucoup pour ce beau travail.


    BPPPI Posté le 12 février, 16:16
    par BPPPI

    Si vous n'êtes pas inscrit sur le site, vous pouvez poster librement (en tant qu'invité).
    Pour cela, indiquez un pseudonyme (nom d'utilisateur) et une adresse email :