Formule calcul excel plus value immobilière en une seule formule

0

Bonjour à tous les amis.


Je suis avocat fiscaliste débutant (1ere année d'exercice) et ma consoeur me demande de créer un tableau excel "modèle" pour divers calcul.


J'ai trouvé comment calculer l'impôt sur le revenu par trancher avec la formule unique suivante : =CHOISIR(EQUIV(H4;{0;9807;27086;72617;153783};1);0;(H4-9807)*0,14;2419,06+(H4-27086)*0,3;16078,06+(H4-72617)*0,41;49355,71+(H4-153783)*0,45)-6048-3024    (mon revenu fiscal de référence est en A4).


J'ai une autre problématique. Je cherche à exprimer dans une formule le calcul du tableau suivant :

Montant de la plus-value imposable

Montant de la taxe

De 50.001 à 60.000 euros

2% PV* - (60.000-PV*) x 1/20

De 60.001 à 100.000 euros 

2%  PV*

De 100.001 à 110.000 euros

3% PV* – (110.000 – PV*) x 1/10

De 110.001 à 150.000 euros 

3% PV*

De 150.001 à 160.000 euros 

4% PV* – (160.000-PV*) x 15/100

De 160.001 à 200.000 euros

4% PV*

De 200.001 à 210.000 euros

5% PV* – (210.000-PV*) x 20/100

De 210.001 à 250.000 euros 

5% PV*

De 250.001 à 260.000 euros 

6% PV* – (260.000-PV*) x 25/100

Supérieur à 260.000 euros

6% PV*

Sachant que contrairement à mon calcul, précédent, on ne cumul par les tranches mais uniquement si on tombe dans une des fourchettes mentionnées.


J'ai essayé de trouver la formule mais mes compétences sont limitées et clle ci ne marche pas :

=SI(X4<50000;0;SI(X4>50001;2%-(60000-X4)*0,05;SI(X4>60001;2%;SI(X4>100001;3%-(110000-X4)*0.1;SI(X4>110001;3%;SI(X4>150001;4%-(110000-X4)*0,15);SI(X4>160001;4%;SI(X4>2000001;5%-(210000-X4)*0,.2;SI(X4>210001;5%;SI(X4>250001;6%-(260000-X4)*0,25;SI(X4>260000;6%)))))))))))


Merci de m'aider. Seul un expert peut répondre à ces questions.

Je paye une bière à celui qui trouvera la formule


Posté le 16 novembre 2017, 15:39
par Paul
Répondre
4

Bonjour Paul,

Voici la formule pour ta plus value :

=SI(E1<=50000;0;SI(E1<=60000;0,02*E1-(60000-E1)*1/20;SI(E1<=100000;0,02*E1;SI(E1<=110000;0,03*E1-(110000-E1)*1/10;SI(E1<=150000;0,03*E1;SI(E1<=160000;0,04*E1-(160000-E1)*15/100;SI(E1<=200000;0,04*E1;SI(E1<=210000;0,05*E1-(210000-E1)*20/100;SI(E1<=250000;0,05*E1;SI(E1<=260000;0,06*E1-(260000-E1)*25/100;SI(E1>260000;0,06*E1)))))))))))

avec ta valeur de plus value en E1

Si ta valeur est en X4 :

Faire ctrl+H et faire remplacer E1 par X4


Si je peux te donner un conseil dans la construction : commencer par la tranche la plus basse; dans cette tranche regarder le seuil le plus élevé puis faire un test logique pour savoir si ton chiffre est inférieur OU égale à ce seuil; si oui faire le calcul de la tranche; sinon continuer à la tranche suivante. puis à la fin finir sur un Supérieur à.


Dis moi si cela te convient,

Cordialement,

Tom

Tom Posté le 16 novembre 2017, 16:26
par Tom
2

Tom, merci infiniment.

Je dois dire que vous me bluffez et que vous m'impréssionez. J'aimerai réellement comprendre le cheminement et je me servirai de votre formule pour comprendre les mécanismes.

La formule fonctionne très bien.

Je ne sais comment vous remercier.

Je travaille dans le milieu de la fiscalité donc n'hésitez pas si vous avez une question quelconque, je ferai une recherche pour vous.

Et je vous remercie également pour votre réactivité et pour avoir pris le temps d'aider un profane tel que moi. Grâce à vous, je vais pouvoir m'acheter une paix sociale.

Cordialement !


Paul


Posté le 16 novembre 2017, 18:31
par Paul
2

Bonjour Paul et Tom

La formule de Tom est naturellement valable, je voulais juste proposer une alternative qui offre une perspective pour l'avenir :

http://www.cjoint.com/c/GKqsG0aQHkJ

Tu cliques sur le lien et tu récupères le petit Excel que j'ai construit pour illustrer mon propos.

En fait je passe par une table qui se trouve dans l'onglet "Table" ce qui a pour principal intérêt que, si nos gouvernants changent d'avis (cela n'arrive presque jamais...) il suffit de modifier la table ET PAS LA FORMULE.

Cela allège aussi un peu la formule qui devient :

=(X4*INDEX(Table!$C$2:$C$12;EQUIV($X$4;Table!$A$2:$A$12;1);1)-(INDEX(Table!$B$2:$B$12;EQUIV($X$4;Table!$A$2:$A$12;1);1)-X4)*INDEX(Table!$D$2:$D$12;EQUIV($X$4;Table!$A$2:$A$12;1);1))

Elle repose sur le principe que la fonction EQUIV va toujours trouver la première valeur inférieure (paramètre 1) et donc la ligne correspondante à la demande et donc les règles à appliquer.

J'ai mis la formule en Y4 (juste à côté de ton X4) mais tu peux naturellement mettre cela où tu veux.

A+

Chris

PS : on pourrait aussi nommer les plages et remplacer dans la formule ce qui la rendrait plus légère à la lecture mais je l'ai laissé ainsi car c'est, je pense, plus facile à comprendre son fonctionnement.

CHRIS Posté le 16 novembre 2017, 19:46
par CHRIS
  • J'aime bien la façon dont est construite ta formule. tout est paramétrable et modulable facilement. – Tom 20 novembre 2017, 14:50
  • Merci Tom et à la prochaine... – CHRIS 20 novembre 2017, 17:46
3

Merci à vous deux les amis !

Posté le 22 novembre 2017, 10:19
par Paul

Si vous n'êtes pas inscrit sur le site, vous pouvez poster librement (en tant qu'invité).
Pour cela, indiquez un pseudonyme (nom d'utilisateur) et une adresse email :